/\*Example of Coding Technique Previously Written for Master's Thesis at GSU\*/

/\*Coded by Morgan Smith on SAS 9.4 and compiled on 9/21/17\*/

/\*Data taken from Publicly Available NHIS (National Health Interview Survey) 2015 Release\*/

/\*Subsetting and Formatting variables via Data Step Programming\*/

Libname nhis "C:\NHIS2012";

libname thesis "C:\Users\mfsmi\Documents\SchoolFiles\Thesis";

options fmtsearch=(nhis);

/\*Section 1: Exploring, extracting and recoding variables of interest from Sample Adult dataset\*/

**Proc** **contents** data=nhis.samadult varnum;

**run**;

/\*Subsetting sample adult for outcome variables and covariates\*/

/\*Hypertension Variables: HYPEV HYPDIFV HYPYR ALCHRC9\*/

/\*Cholesterol Variables: CHLEV CHLYR APSCHCHK\*/

/\*Diabetes Variables: DIBEV ALCHRC10 APSBSCHK\*/

/\*BMI Variables: AHEIGHT AWEIGHTP BMI\*/

**Data** Outcomes (keep= HHX FMX FPX WTFA\_SA STRAT\_P PSU\_P Age\_p SMKSTAT2 Region Sex R\_Maritl HYPEV hypdifv hypyr CHLEV CHLYR

DIBEV BMI);

set nhis.samadult;

**run**;

/\*Exploring categorical variables\*/

**proc** **freq** data=outcomes;

table SMKSTAT2 Region Sex R\_Maritl HYPEV hypdifv hypyr CHLEV CHLYR DIBEV;

**run**;

/\*Exploring Continuous Variables\*/

**proc** **univariate** data=outcomes plot normal;

var bmi age\_p;

**run**;

/\*Section 2: Formatting variables as necessary\*/

/\*Subsetting Sample adult data set for weighting variable and Creating age\_cat dichotomous variable as indicator of being in 85+ group; recoding smkstat2 into\*/

/\*dichotomous indicator of ever smoking; recoding sex variable into new\_sex; collapsing marital status into dichotomous with\*/

/\*for married/partnered and Not Married; \*/

/\*Formats\*/

**Proc** **Format** lib=nhis;

value

Age\_Cat

**1**="85+ years"

**0**="18-84 years";

value

smokes

**1**="smoked at some point"

**0**="Never Smoked";

value

sex

**1** ="Male"

**0** ="Female";

value

M\_Status

**1**="Married/Partnered"

**0**="Not Married";

Value

HBP2X

**1**= "Hypertensive on 2+ Occasions"

**0**= "Non-Hypertensive";

value

Diabetes

**1**="Ever told diabetic"

**0**="No Diabetes";

value

highC

**1**="Ever told had high cholesterol"

**0**="No High Cholesterol";

**run**;

/\*Creating additional needed categorical variables and saving as permanant copy\*/

**Data** thesis.outcomes (drop=hypev hypdifv HYPYR dibev chlev CHLYR bmi smkstat2 r\_maritl sex);

set outcomes;

/\*Age\_Cat variable to account for grouping >=85\*/

if age\_p ne **.** then do;

if age\_p ge **85** then age\_cat=**1**;

else age\_cat=**0**;

end;

/\*Creating dichotomous indicator of ever having smoked\*/

/\*Current Everyday, Current Some, Former, Smoker current Status Unknown \*/

if smkstat2 in (**1**, **2**, **3**, **5**) then smokes=**1**;

/\*Never Smoked\*/

else if smkstat2=**4** then smokes=**0**;

/\*Unknown\*/

else if smkstat2=**9** then smokes= **.**;

/\* Recoding Sex\*/

/\* Male\*/

If SEX=**1** then NEW\_SEX=**1**;

/\* Female\*/

If SEX=**2** then NEW\_SEX=**0**;

/\*Recoding marital Status\*/

if r\_maritl in (**1**, **2**, **3**, **6**, **8**) then Married=**1**;

else if r\_maritl in (**0**, **4**, **5**, **7**) then Married=**0**;

else if r\_maritl=**9** then Married= **.**;

if r\_maritl in (**1**, **2**, **3**, **6**) then MarriedMinusPartner=**1**;

else if r\_maritl in (**0**, **4**, **5**, **7**, **8**) then MarriedMinusPartner=**0**;

else if r\_maritl=**9** then Married= **.**;

if r\_maritl in (**1**, **2**, **3**) then MarriedMinusPandSep=**1**;

else if r\_maritl in (**0**, **4**, **5**, **7**, **6**, **8**) then MarriedMinusPandSep=**0**;

else if r\_maritl=**9** then Married= **.**;

/\*told hypertensive 2+ times ever corrected for ever told variable; Next creating variable for told hypertensive in past year\*/

/\* Yes: Ever Hypertensive\*/

if HYPEV=**1** then do;

/\* told hypertensive on 2+ occasions\*/

if hypdifv=**1** then HBP=**1**;

/\* not told on 2+ occasions\*/

else if hypdifv=**2** then HBP=**0**;

/\* Refused and don't know\*/

else if hypdifv in (**7**, **8**, **9**) then hbp=**.**;

end;

/\* No: Never Hypertensive\*/

if hypev=**2** then HBP=**0**;

/\* Refused and Don't Know\*/

else if hypev in (**7**,**9**) then HBP=**.**;

/\* Hypertensive in Past year\*/

if hbp=**1** then do;

if hypyr=**1** then HBP\_YR=**1**;

else if hypyr=**2** then HBP\_YR=**0**;

else if hypyr in (**7**, **8**, **9**) then HBP\_YR=**.**;

end;

if hbp=**0** then HBP\_YR=**0**;

else if hbp=**.** then HBP\_YR=**.**;

/\* Recoding High Cholesterol Variables for ever and for in past year\*/

/\* Yes: ever told cholesterol was high\*/

if CHLEV=**1** then HighC=**1**;

/\* No: never told cholesterol was high\*/

else if CHLEV=**2** then HighC=**0**;

/\* Refused and Don't Know\*/

else if CHLEV in (**7**,**8**,**9**) then HighC=**.**;

/\* Told cholesterol was high in past year\*/

if HighC=**1** then do;

if chlyr=**1** then HighC\_yr=**1**;

else if chlyr=**2** then HighC\_yr=**0**;

else if chlyr in (**7**,**8**,**9**) then HighC\_yr=**.**;

end;

if HighC=**0** then HighC\_yr=**0**;

else if HighC=**.** then HighC\_yr=**.**;

/\* Recoding Diabetes Variables\*/

/\* Yes\*/

if DIBEV=**1** then DIABETES=**1**;

/\* No and Borderline\*/

else if DIBEV IN (**2**,**3**) then DIABETES=**0**;

/\* Refused and Don't Know\*/

else if DIBEV in (**7**,**8**,**9**) then DIABETES=**.**;

/\* Recoding BMI\*/

if BMI=**99.99** then New\_BMI=**.**;

else New\_BMI=BMI;

format age\_cat age\_cat. smokes smokes. HBP HBP2X. HighC HighC. Diabetes Diabetes. new\_sex sex. Married M\_Status.;

**run**;

/\*Quality Checking Created Variables\*/

**PROC** **CONTENTS** DATA=THESIS.OUTCOMES VARNUM;

**RUN**;

**proc** **freq** data=thesis.outcomes;

table hbp hbp\_yr highc highc\_yr;

**run**;

**proc** **means** data=nhis.samadult n mean median std min max nmiss q1 q3;

var bmi;

**run**;

**proc** **means** data=thesis.outcomes n mean median std min max nmiss q1 q3 ;

var new\_bmi;

**run**;

/\*checking frequencies of final variables-all checked out\*/

**proc** **freq** data=thesis.outcomes;

table new\_bmi diabetes highc highc\_yr hbp hbp\_yr married new\_sex age\_cat/list;

**run**;